|
BASIC Listing |
The Wild Bunch is mostly Sinclair BASIC. The commercial tape stores the
program as a single PROGRAM block with a one-line stub that
LIST will show, then the real tokenised program with line 15's
header deliberately corrupted so listing stops. This page is a recovered
LIST of that program (507 lines). Line 15 is
reconstructed from the prompt text and the pre-production tape; every other
line is taken from the post-load snapshot.
Line 1 enters the machine-code stub with
RANDOMIZE USR (VARS-116). The digits in the line say
140, but the hidden floating-point value is 116.
In this snapshot that is Run_Bootstrap. The tap2sna start address
Run_Bootstrap_Apply sits further into the same stub. Game logic, text and data are
the BASIC below; the stub holds graphics helpers and the USR entry.
1 RANDOMIZE USR ((PEEK 23627)+((PEEK 23628)*256)-116)
15 PRINT "WHAT NAME DO YOU GO BY?": INPUT "ENTER NAME "; LINE N$: IF N$="" THEN GO TO VAL "15"
20 BEEP .4,-10: CLS : PRINT AT 8,3;"ENTER LEVEL OF DIFFICULTY": INPUT " LEVEL 1,2 OR 3 "; LINE E$: LET E$=E$+" ": IF CODE E$(1)>51 OR CODE E$(1)<49 THEN GO TO VAL "20"
22 LET LV=VAL E$+U
30 BEEP .5,30: CLS : PRINT AT 10,10;"PLEASE WAIT": LET LM=3: LET SC=O: LET JB=O: LET L=6: LET CS=1500: LET DT=O: RANDOMIZE O: DIM T(5,5): RESTORE 9110: FOR N=U TO 5: FOR A=U TO 5: READ S: LET T(N,A)=S: NEXT A: NEXT N
40 LET CS=1450: DIM U(5,INT PI): RESTORE VAL "9120": FOR N=U TO 5: FOR A=U TO 3: READ S: LET U(N,A)=S: NEXT A: NEXT N
50 DIM K$(16,20): RESTORE VAL "9140": FOR N=U TO 16: READ K$(N): NEXT N
60 DIM K(16): RESTORE VAL "9145": FOR N=U TO 16: READ K(N): NEXT N:
70 DIM I(16): FOR N=U TO 16: LET I(N)=O: NEXT N: LET I(6)=5: LET I(4)=U: DIM R(5): RESTORE VAL "9095": FOR N=U TO 5: READ R(N): NEXT N: DIM D$(5,19)
115 FOR N=U TO 5: RESTORE VAL "9000"+INT (RND*12)+U: READ l$: LET D$(n)=L$
135 FOR A=U TO N: IF A=N THEN GO TO VAL "145"
140 IF D$(N)=D$(A) THEN GO TO VAL "115"
145 NEXT A: NEXT N
155 DIM B$(5,15): RESTORE VAL "9015": FOR N=U TO 5: READ B$(N): NEXT N
165 DIM V(5): FOR N=U TO 5: LET V(N)=R: NEXT N
170 LET MB=INT (RND*5)+U
180 DIM T$(5,14): RESTORE VAL "9045": FOR N=U TO 5: READ T$(N): NEXT N: GO TO VAL "8900"
310 BORDER U: PAPER R: CLS : LET S$=" ": FOR N=U TO 30: PRINT AT U,N;"~";AT 11,N;"~": NEXT N: FOR N=R TO 10: PRINT AT N,U;"~"; PAPER 6;S$; PAPER R;"~": NEXT N
315 PRINT PAPER 6;AT 7,6;"_";AT 2,9;"4";AT 5,3;"5 _";AT 6,9;"_ 3";TAB 21;"1";AT 9,10;"2";AT 3,27;"N";AT 4,27;"↑"
320 PLOT 92,136: DRAW 5,9: DRAW INT PI,-5: PLOT 97,136: DRAW 5,7: DRAW 5,-7: PLOT 105,139: DRAW INT PI,6: DRAW 5,-9: PLOT 111,140: DRAW 5,4: DRAW 6,-8: CIRCLE 219,144,12
325 PRINT AT 13,R;"1=DRY GULCH : 2=DODGE CITY";TAB R;"3=NUGGET CITY : 4=BULLETVILLE";TAB 8;"5=DEADMANS CREEK";AT 16,7;"------------------"
330 RESTORE VAL "9050": FOR N=U TO 5: READ Z: READ X: BEEP Z/4,X+3: NEXT N: RETURN
480 GO SUB VAL "7500"
485 IF UM=TN THEN GO TO VAL "487"
486 GO TO VAL "500"
487 BORDER PI: PAPER PI: CLS : PRINT : PRINT : PRINT : PRINT "YOU HAVE ENTERED ";T$(TN): PRINT : PRINT "AGENT CHARLES A.SIRINGO OF THE": PRINT : PRINT "PINKERTON DETECTIVE AGENCY": PRINT : PRINT "IS WAITING FOR YOU.": PRINT : PRINT "HE ARRESTS YOU ON A CHARGE OF": PRINT : PRINT "MURDER. YOU ARE GOING TO PRISON": PRINT : PRINT "FOR A LONG LONG TIME....": GO TO VAL "2725"
505 BORDER INT PI: PAPER U: CLS : PRINT PAPER 4;AT U,INT PI;;"YOU ARE IN ";T$(TN): PRINT : PRINT TAB INT PI; PAPER U;"YOU CAN DO THE FOLLOWING:-"
510 PRINT AT 6,4;"1-GO TO SALOON",,TAB 4;"2-GO TO SHERIFFS' OFFICE",,TAB 4;"3-GO TO STORE",,TAB 4;"4-GO TO TELEGRAPH OFFICE",,TAB 4;"5-MOVE ON",,,TAB 4;"6-STATUS";AT 19,2;"PRESS NUMBER OF YOUR CHOICE"
520 BEEP .001,45: IF INKEY$="1" THEN GO TO VAL "1000"
521 IF INKEY$="2" THEN GO TO VAL "3000"
522 IF INKEY$="3" THEN GO TO VAL "7666"
523 IF INKEY$="4" THEN GO TO VAL "2500"
524 IF INKEY$="5" THEN GO TO VAL "6000"
525 IF INKEY$="6" THEN GO TO VAL "7800"
535 BEEP .005,0: GO TO VAL "520"
1010 BORDER U: PAPER R: CLS : PRINT PAPER 4;AT R,5;"YOU'RE IN THE SALOON"; PAPER R;AT 4,7;"DO YOU WANT TO:-"
1015 PRINT AT 6,6;"1) DRINK": PRINT : PRINT TAB 6;"2) PLAY POKER": PRINT : PRINT TAB 6;"3) LOOK AROUND": PRINT : PRINT TAB 6;"4) LEAVE";AT 15,R;"PRESS NUMBER OF YOUR CHOICE": BEEP .3,20
1020 BEEP .01,PI: IF INKEY$="1" THEN GO TO VAL "1150"
1021 IF INKEY$="2" THEN GO TO VAL "1250"
1022 IF INKEY$="3" THEN GO TO VAL "2000"
1024 IF INKEY$="4" THEN GO TO VAL "500"
1030 BEEP .005,-PI: GO TO VAL "1020"
1150 PAPER 4: CLS : PRINT AT 4,6;"YOU ARE AT THE BAR": PRINT : PRINT : PRINT : PRINT TAB 5;"WHAT WILL YOU HAVE ?": PRINT : PRINT TAB 6;"1) BEER ($1)": PRINT : PRINT TAB 6;"2) RED EYE ($2)"
1155 BEEP .6,25: INPUT "ENTER (1 OR 2) "; LINE E$: LET E$=E$+" ": IF CODE E$(U)=49 OR CODE E$(U)=50 THEN LET H=VAL E$(U): GO TO VAL "1160"
1157 GO TO VAL "1155"
1160 IF MU<H THEN PRINT : PRINT TAB 5;"YOU CAN'T AFFORD IT!!": GO SUB VAL "9231": GO TO VAL "1000"
1165 IF H=U THEN LET IS=IS+U: LET CS=CS+10: LET MU=MU-H: PRINT : PRINT TAB 6;"ONE BEER COMING UP": PRINT : PRINT "THAT'S WORTH 10 STRENGTH POINTS": GO TO VAL "1175"
1170 IF H=R THEN LET IS=IS+INT PI: LET CS=CS+25: LET MU=MU-H: PRINT : PRINT TAB 4;"ONE RED EYE COMING UP": PRINT : PRINT "THAT'S WORTH 25 STRENGTH POINTS"
1175 FOR N=-10 TO 10: BEEP .1,N: BEEP .1,N+U: NEXT N
1180 IF IS>LM THEN CLS : LET CS=CS-IS*20: PRINT AT 6,INT PI;"YOU FEEL DIZZY AND STUMBLE": PRINT : PRINT " INTO A LONESOME COWBOY,WHO": PRINT : PRINT " HITS YOU VERY HARD,YOUR": PRINT : PRINT " STRENGTH IS ";CS: GO TO VAL "1190"
1185 GO TO VAL "1000"
1190 FOR N=U TO 50: BEEP .1,RND*50: NEXT N: IF CS<=0 THEN GO TO VAL "2435"
1195 GO TO VAL "500"
1200 BEEP .1,5: BEEP .1,10: BEEP .1,15: INPUT " PRESS ENTER TO CONTINUE "; LINE H$: RETURN
1250 BORDER 4: PAPER 4: CLS : IF MU<3 THEN PRINT AT 11,5;"YOU CAN'T AFFORD IT": GO SUB VAL "9231": GO TO VAL "1000"
1260 IF MU>120 THEN PRINT AT 7,8;"THERE IS NO ONE": PRINT : PRINT TAB 6;"TO PLAY POKER WITH.": FOR N=U TO 30: BEEP .05,N*-U: BEEP .02,N: NEXT N: GO TO VAL "1000"
1265 PRINT AT 6,4;"YOU PLAY POKER WITH": PRINT : PRINT TAB 4;"THE TOWN GAMBLER....": BEEP .2,U: BEEP .4,10: GO SUB VAL "1200"
1270 LET S$=" ": LET C=INT (RND*3)+U
1275 LET YH=INT (RND*16)+9060: LET GH=INT (RND*16)+9060: IF C=U THEN LET GH=GH+R: IF GH>9075 THEN LET GH=9075
1290 IF GH=YH THEN GO TO VAL "1275"
1305 LET POT=R: LET MU=MU-U:: RESTORE YH: READ Y$: RESTORE GH: READ G$
1310 CLS : PRINT AT R,7;"THE ANTE IS $1.00";AT 4,12;"POT=$";POT
1315 PRINT AT 6,R;"YOUR HAND:";AT 8,12;Y$
1320 PRINT AT 10,R;"YOU HAVE $";INT MU;TAB 17;":LAST BET $0"
1325 LET BL=RND*10: IF GH>9063 OR BL>6 THEN GO TO 1350
1330 PRINT AT 17,R;"GAMBLER THROWS IN HIS CARDS": LET MU=MU+POT: GO SUB VAL "1200": GO SUB VAL "1500": GO TO VAL "1490"
1350 LET NB=INT (RND*4)+R: IF GH>9073 THEN LET NB=5
1355 FOR N=U TO NB
1360 IF N=U THEN LET BET=R: PAUSE 150: PRINT AT 13,4;"THE GAMBLER BETS $";BET: LET POT=POT+BET: GO SUB VAL "1510": GO SUB VAL "1200": GO SUB VAL "1500": GO TO VAL "1435"
1363 IF N=NB AND BL>6 THEN GO TO VAL "1330"
1365 IF N=NB THEN LET POT=POT+BET: PRINT AT 17,R;"THE GAMBLER SEES YOU": GO SUB VAL "1510": GO SUB VAL "1200": GO TO VAL "1475"
1370 IF BL>6 THEN GO TO VAL "1380"
1375 IF I$="C" THEN LET POT=POT+BET: PRINT AT 17,INT PI;"THE GAMBLER CALLS YOUR BET": GO SUB VAL "1510": GO SUB VAL "1200": GO TO VAL "1430"
1380 LET BET=BET+INT (RND*10)+U: LET POT=POT+BET: PRINT AT 17,4;"HE RAISES THE BET TO $";BET: GO SUB VAL "1510": GO SUB VAL "1200": GO TO VAL "1430"
1430 IF INT MU-BET<O THEN GO TO VAL "1470"
1435 GO SUB VAL "1500": PRINT AT 12,INT PI;"WHAT DO YOU WANT TO DO?";AT 14,8;"A)THROW IN HAND";TAB 8;"B)CALL HIS BET";TAB 8;"C)RAISE";TAB 8;"D)SEE HIM"
1440 BEEP .4,10: INPUT " ENTER LETTER "; LINE I$: BEEP .3,30: BEEP .2,20
1445 IF I$="A" THEN GO SUB VAL "1500": GO TO VAL "1490"
1450 IF I$="B" THEN LET MU=MU-BET: LET POT=POT+BET: GO SUB VAL "1500": GO SUB VAL "1510": PRINT AT 17,10;"OK. YOU CALL": PAUSE 150: GO TO VAL "1469"
1455 IF I$="D" THEN LET MU=MU-BET: LET POT=POT+BET: GO TO VAL "1475"
1457 IF I$="C" AND MU>=BET+U THEN PRINT AT 19,R;"WHAT DO YOU BET? (MIN.$";BET+U;")": INPUT " ENTER AMOUNT "; LINE E$: LET E$=E$+" ": IF CODE E$(U)<58 AND CODE E$(U)>48 THEN GO TO VAL "1462"
1460 IF I$="C" THEN GO TO 1457
1461 GO TO VAL "1440"
1462 LET RA=VAL E$: IF RA<BET+U THEN GO TO VAL "1460"
1463 IF RA>MU THEN GO TO VAL "1460"
1464 GO SUB VAL "1500": LET MU=MU-RA: LET POT=POT+RA: LET BET=RA: PRINT AT 17,INT PI;"YOU RAISE THE BET TO $";BET: GO SUB VAL "1510": PAUSE 150: GO SUB VAL "1500": NEXT N
1465 GO TO VAL "1440"
1467 PRINT AT 17,R;"YOU CAN'T AFFORD TO RAISE.": GO SUB VAL "9230": GO TO VAL "1435"
1469 NEXT N
1470 GO SUB VAL "1500": PRINT AT 17,O;"YOU CAN'T AFFORD TO PLAY ANYMORE": GO SUB VAL "9230": GO SUB VAL "1200": GO TO VAL "1000"
1475 GO SUB VAL "1500": IF GH>YH THEN PRINT AT 12,R;"GAMBLER'S HAND:": PRINT : PRINT TAB 12;G$;AT 17,2;"THE GAMBLER WINS THAT ONE": GO SUB VAL "1510": GO SUB VAL "1200": GO SUB VAL "1500": GO TO VAL "1490"
1480 IF GH<YH THEN LET MU=MU+POT: GO SUB VAL "1510": PRINT AT 12,R;"GAMBLER'S HAND:": PRINT : PRINT TAB 12;G$;AT 17,8;"YOU WIN THAT ONE": GO SUB VAL "1200": GO SUB VAL "1500"
1490 IF MU>120 THEN CLS : PRINT AT 10,6;"THE GAMBLER QUITS!!": GO SUB VAL "1200": GO TO VAL "1000"
1491 PRINT AT 16,R;"WOULD YOU LIKE ANOTHER HAND?": PRINT : PRINT TAB 13;"(Y/N)"
1492 BEEP .03,U: IF INKEY$="Y" THEN GO TO VAL "1498"
1495 IF INKEY$="N" THEN GO TO VAL "1000"
1497 BEEP .01,O: GO TO VAL "1492"
1498 IF MU<INT PI THEN GO TO VAL "1250"
1499 GO TO VAL "1275"
1500 FOR K=12 TO 21: PRINT AT K,0;S$: NEXT K: RETURN
1510 PRINT AT 4,17;POT;AT 10,12;INT MU;" ";AT 10,28;BET: RETURN
2001 INK 9: PAPER INT PI: CLS : IF DT=U THEN PRINT AT 10,R;"THERE'S NOBODY SPECIAL HERE": PAUSE 150: GO TO VAL "1000"
2010 IF RND*LV<U THEN GO TO VAL "2100"
2015 RESTORE 9000+INT (RND*12)+U: READ J$
2025 FOR N=U TO 5
2030 IF J$=D$(N) THEN GO TO VAL "2015"
2035 NEXT N: LET BG=U
2040 PRINT AT 5,O;"A MAN WALKS INTO THE SALOON WITH": PRINT : PRINT TAB 3;J$
2045 LET DT=U: GO TO 2200
2100 LET BG=O: LET M=INT (RND*5)+U
2110 IF V(M)<R THEN GO TO 2100
2112 IF M=MB AND V(U)+V(R)+V(3)+V(4)+V(5)>6 THEN GO TO 2100
2115 LET J$=D$(M): GO TO 2040
2200 PRINT INK 6;AT 12,U;"DO YOU WANT TO CHALLENGE HIM ?": PRINT : PRINT TAB 13;"(Y/N)"
2210 IF INKEY$="Y" THEN GO TO VAL "2300"
2215 BEEP .01,20: BEEP .01,30
2220 IF INKEY$="N" THEN LET DT=U: GO TO VAL "1000"
2230 GO TO VAL "2210"
2300 CLS : PRINT AT 4,INT PI;"DO YOU THINK HE IS :-": PRINT : PRINT " 1) ";B$(U): PRINT : PRINT " 2) ";B$(R): PRINT : PRINT " 3) ";B$(3): PRINT : PRINT " 4) ";B$(4): PRINT : PRINT " 5) ";B$(5): PRINT : PRINT " ENTER NUMBER OF CHOICE."
2310 BEEP .2,10: BEEP .3,-10: INPUT LINE E$: LET E$=E$+" ": IF CODE E$(U)<49 OR CODE E$(U)>53 THEN GO TO VAL "2310"
2315 LET A=VAL E$: IF A<U THEN GO TO VAL "2310"
2320 IF A>5 THEN GO TO VAL "2310"
2330 BORDER O: CLS : PRINT AT 6,4;"DO YOU WANT TO :-": PRINT : PRINT TAB 5;"1) TAKE HIM PRISONER": PRINT : PRINT TAB 5;"2) HAVE A GUN FIGHT": PRINT : PRINT : PRINT TAB 9;"PRESS 1 OR 2"
2335 IF INKEY$="1" THEN LET E$="CAPTURED ": LET I$="LAUGHS": LET TP=U: GO TO VAL "2400"
2337 BEEP .01,PI: BEEP .01,PI*PI
2340 IF INKEY$="2" THEN LET E$="KILLED ": LET I$="FROWNS": LET TP=O: LET GF=U: GO TO VAL "5000"
2345 GO TO VAL "2335"
2400 BORDER 6: CLS : PRINT AT 7,R;"YOU SAY;""I'M TAKING YOU IN."""
2407 IF I(4)+I(5)+I(7)<=O THEN PRINT AT 10,INT PI;"THE MAN SEES THAT YOU HAVE": PRINT : PRINT " NO GUN AND RUNS OFF": LET SC=SC-50: GO TO VAL "2422"
2410 IF BG=U THEN GO TO VAL "2450"
2414 IF RND*5>1.7 THEN GO TO VAL "2450"
2415 PRINT AT 10,INT PI;"BUT,THE MAN THROWS A BOTTLE": PRINT : PRINT " AT YOU AND RUNS OFF.": LET CS=CS-50
2422 FOR N=18 TO 30: BEEP .3,N: BEEP .2,N*-U: NEXT N: IF CS<=O THEN GO TO VAL "2435"
2430 GO TO VAL "1000"
2435 BORDER O: PAPER O: CLS : PRINT AT 10,O;"YOU HAVE DIED FROM YOUR INJURIES":
2440 RESTORE VAL "9100": FOR N=U TO 11: READ M: READ W: BEEP M/3,W: NEXT N: LET M$="YOU RAN OUT OF STRENGTH!": GO TO VAL "8500"
2450 PRINT AT 11,1;"YOU TAKE THE MAN,AT GUN POINT": PRINT : PRINT " TO THE SHERIFF'S OFFICE": GO SUB VAL "2455": GO TO VAL "2460"
2455 RESTORE VAL "9080": FOR N=U TO 10: READ K: READ G: BEEP K/3,G: NEXT N: RETURN
2460 BORDER 5: CLS : PRINT AT 4,U;"YOU TELL THE SHERIFF YOU HAVE": PRINT : PRINT TAB 4;E$;B$(A)
2465 IF D$(A)=J$ AND TP=U THEN GO TO VAL "2495"
2466 IF D$(A)=J$ AND GF=U THEN GO TO VAL "2700"
2467 PRINT AT 9,R;"THE SHERIFF ";I$;" AND SAYS;": PRINT : PRINT " ""THAT'S NOT ";B$(A);"."""
2468 IF V(A)=U THEN LET C$="HE HAS BEEN PUT IN JAIL"
2469 IF V(A)=O THEN LET C$="HE WAS KILLED"
2470 IF D$(A)<>J$ THEN LET C$="HE DOESN'T FIT THE DESCRIPTION"
2471 IF BG=U THEN RESTORE 9150+INT (RND*4)+U: READ Z$: PRINT AT 14,4;"""THAT'S ";Z$;"""": GO TO VAL "2480"
2472 PRINT AT 14,R;C$
2480 IF TP=U THEN PRINT AT 17,7;"HE LETS THE MAN GO": GO SUB VAL "2482": GO TO VAL "2483"
2481 PRINT AT 17,7;"HE COVERS THE BODY": GO SUB VAL "2482": GO TO VAL "2720"
2482 FOR N=50 TO -10 STEP -U: BEEP .1,N: BEEP .05,N/2: NEXT N: RETURN
2483 CLS : IF MU<5 THEN LET W=MU: LET MU=O: GO TO VAL "2485"
2484 LET W=INT (MU/10): LET MU=MU-W
2485 PRINT AT 6,4;"THE SHERIFF FINES YOU $";W: PRINT : PRINT TAB 4;"FOR WASTING HIS TIME THEN": PRINT : PRINT TAB 4;"THROWS YOU OUT"
2486 FOR N=30 TO -30 STEP -U: BEEP .05,N: BEEP .05,N-R: NEXT N: GO TO VAL "500"
2495 PRINT AT 12,R;"THE SHERIFF AGREES AND PUTS": PRINT : PRINT TAB 4;"HIM BEHIND BARS.": PRINT : PRINT TAB R;"YOU RECEIVE $";R(A);" REWARD": LET V(A)=U: LET MU=MU+R(A): LET SC=SC+200: GO SUB VAL "2498"
2496 IF B$(A)=B$(MB) THEN GO TO VAL "9600"
2497 GO TO VAL "500"
2498 RESTORE VAL "9085": FOR N=U TO 18: READ K: READ H: BEEP K/5,H: NEXT N: RETURN
2501 IF MU<=100 THEN LET BB=20: GO TO VAL "2550"
2505 LET BB=20+INT (RND*50)+U
2550 BORDER U: PAPER 5: CLS : PRINT AT 6,U;"YOU GO TO THE TELEGRAPH OFFICE",,," THE CLERK SAYS HE WILL SHOW",,," YOU THE LATEST TELEGRAPHS",,," FOR $";BB;AT 16,6;"DO YOU AGREE ?(Y/N)"
2555 BEEP .02,30: IF INKEY$="N" THEN GO TO VAL "500"
2560 IF INKEY$="Y" THEN GO TO VAL "2570"
2565 BEEP .02,-20: GO TO VAL "2555"
2570 IF MU<BB THEN CLS : PRINT AT 8,0;"YOUR INTENTIONS ARE BIGGER THAN",,,"YOUR WALLET.YOU DON'T HAVE $";BB: FOR N=-20 TO 25: BEEP .1,N: BEEP .05,N*-U: NEXT N: GO TO VAL "500"
2575 LET MU=MU-BB
2585 BORDER O: PAPER 7: CLS : PRINT AT 4,U;"TELEGRAPH FROM ";T$(UM);AT 8,3;"PINKERTON AGENT CHARLES A.",,," SIRINGO ARRIVED TODAY IN",,," SEARCH OF FUGITIVE KNOWN",,," AS ";N$: INPUT " PRESS ENTER"; LINE H$
2590 IF JB<>O THEN GO SUB VAL "2610"
2595 GO TO VAL "2620"
2610 CLS : PRINT AT 4,4;"TELEGRAPH FROM KNOXVILLE";AT 8,R;"THE OUTLAW ";B$(JB),,," ESCAPED FROM KNOXVILLE COUNTY",,," JAIL.",,,," REWARD FOR RECAPTURE $";R(JB): INPUT " PRESS ENTER"; LINE H$: LET JB=O: RETURN
2620 LET X=INT (RND*12)+U
2625 IF X<8 THEN GO TO VAL "500"
2630 IF X=12 THEN LET W$="UNION PACIFIC RAILROAD CO.": LET X$="TRAIN"
2631 IF X=11 THEN LET W$="GREAT NORTHERN RAILROAD CO.": LET X$="TRAIN"
2632 IF X=10 THEN LET W$="DENVER": LET X$="FIRST NATIONAL BANK"
2633 IF X=9 THEN LET W$="MONTPELIER,IDAHO": LET X$="FIRST NATIONAL BANK"
2634 IF X=8 THEN LET W$="WINNEMUCCA,NEVADA": LET X$="FIRST NATIONAL BANK"
2635 CLS : PRINT AT 4,O;"TELEGRAPH FROM ";W$;AT 8,R;"WILD BUNCH CARRIED OUT RAID",,," ON ";X$;AT 12,R;"REWARDS RAISED BY $50": FOR N=U TO 5: LET R(N)=R(N)+50: NEXT N: INPUT " PRESS ENTER"; LINE H$: GO TO 500
2700 PRINT AT 12,2;"THE SHERIFF AGREES AND CALLS": PRINT : PRINT " THE UNDERTAKER.": PRINT : PRINT " YOU RECEIVE $";R(A);" REWARD.": LET MU=MU+R(A): LET SC=SC+500: LET V(A)=O: IF I(4)>O AND I(6)>O THEN LET I(6)=I(6)-U: GO SUB VAL "2498": GO TO VAL "2710"
2705 LET I(5)=I(5)-U: GO SUB VAL "2498"
2710 IF B$(A)=B$(MB) THEN GO TO VAL "9700"
2715 GO TO VAL "500"
2720 BORDER 0: PAPER 0: CLS : PRINT AT 7,O;"HE ARRESTS YOU FOR MANSLAUGHTER": PRINT : PRINT "YOU'LL BE IN JAIL FOR QUITE A": PRINT : PRINT "LONG TIME....."
2725 FOR N=7 TO -20 STEP -U: BEEP .2,N: BEEP .05,N+3: NEXT N: GO SUB VAL "9500": GO TO VAL "9870"
3000 BORDER R: PAPER INT PI: INK 9: CLS
3005 BEEP .2,15: BEEP .25,-15: PRINT AT 6,5;"YOU GO TO THE SHERIFFS": PRINT : PRINT TAB 5;"OFFICE TO LOOK AT THE": PRINT : PRINT TAB 5;"LATEST WANTED POSTERS": PRINT : PRINT TAB 5;"ON MEMBERS OF THE WILD": PRINT : PRINT TAB 5;"BUNCH."; FLASH U;AT 17,12;"ANY KEY": FLASH O
3010 IF INKEY$<>"" THEN GO TO VAL "7000"
3020 BEEP .01,INT PI: BEEP .02,15
3025 GO TO VAL "3010"
4005 LET DT=O: LET JM=INT (RND*3)+U: LET UM=U(UM,JM)
4035 LET R$="-------------------------------": LET HS=6: LET HL=O: BORDER 5: PAPER 5: CLS : PRINT "YOU START YOUR JOURNEY....": IF I(U)<=O THEN LET G=G*R: PRINT : PRINT "BUT YOU HAVE NO HORSE SO THE": PRINT "JOURNEY WILL TAKE ";G;" DAYS": GO TO 4080
4040 IF I(R)<=O THEN LET G=G+R: PRINT : PRINT "BUT YOU HAVE NO SADDLE SO THE": PRINT "JOURNEY WILL TAKE ";G;" DAYS...."
4080 LET JY=O: FOR N=U TO G: LET JY=JY+U: PRINT : PRINT "DAY ";JY;" OF JOURNEY": GO SUB 4960
4095 IF I(10)>=U THEN LET I(10)=I(10)-U
4110 LET NN=INT (RND*R)+U: LET TS=O: LET DI=PI: LET OR=PI: LET MI=PI: FOR W=U TO NN: POKE 23692,255: LET FO=O: LET KK=INT (RND*12): IF KK=11 AND I(U)=U THEN GO SUB 4970: GO TO 4126
4115 IF DE=U AND N=R OR DE=U AND N<>U AND N<=G-U THEN GO TO VAL "4130"
4116 IF MT=U AND N=R OR MT=U AND N<>U AND N<=G-U THEN GO TO VAL "4140"
4117 PRINT : PRINT "YOU ARE ON THE OPEN RANGE": IF OR=PI THEN GO SUB VAL "4200": LET OR=O
4118 GO SUB VAL "4701": IF KK=INT PI THEN LET F$="BUFFALO"
4119 IF KK=5 OR KK=6 THEN GO SUB VAL "4870": GO TO VAL "4126"
4120 IF KK=U THEN LET F$="LONGHORN"
4121 GO SUB VAL "4700"
4122 PRINT : PRINT "A ";M$;",";U$;" ";F$: PRINT E$;" (STRENGTH ";BS;")": PRINT : PRINT "YOUR STRENGTH IS ";CS
4123 GO SUB VAL "4950": IF H$="F" THEN GO SUB VAL "4730"
4124 IF H$="R" THEN GO SUB VAL "4780"
4125 IF H$="B" THEN GO SUB VAL "4795": IF TS=PI THEN GO TO VAL "4123"
4126 LET TS=O: BEEP .7,PI: PRINT : PRINT R$: NEXT W: PAUSE 100: NEXT N: GO TO VAL "480"
4130 PRINT : PRINT "YOU'RE IN THE DESERT": IF DI=PI THEN GO SUB VAL "4200": GO SUB VAL "4850": GO SUB VAL "4845": GO SUB VAL "4855": GO SUB VAL "4990"
4131 GO SUB VAL "4701"
4133 IF KK=INT PI THEN LET F$="SCORPION"
4134 IF KK=U THEN LET F$="RATTLE SNAKE"
4135 IF KK=O THEN LET N=N-2: PRINT : PRINT "A SANDSTORM ADDS 2 DAYS": PRINT "TO YOUR JOURNEY": GO TO VAL "4126"
4136 IF KK=5 OR KK=6 THEN GO SUB VAL "4870": GO TO VAL "4126"
4137 GO TO VAL "4121"
4140 PRINT : PRINT "YOU'RE IN THE MOUNTAINS": IF MI=PI THEN GO SUB VAL "4200": GO SUB VAL "4850": GO SUB VAL "4845": GO SUB VAL "4855": GO SUB VAL "4975": IF I(13)<=O OR I(15)<=O THEN GO SUB VAL "4860": GO SUB VAL "4990"
4142 IF KK=O THEN PRINT : PRINT "A ROCKFALL ADDS 2 DAYS": PRINT "TO YOUR JOURNEY": LET N=N-R: GO TO VAL "4126"
4143 IF KK=5 OR KK=6 THEN GO SUB VAL "4870": GO TO VAL "4126"
4145 GO SUB VAL "4701"
4147 IF KK=INT PI THEN LET F$="MOUNTAIN LION"
4148 IF KK=U THEN LET F$="GRIZZLY BEAR"
4149 GO TO VAL "4121"
4200 IF I(10)<=O THEN LET CS=CS-20: PRINT : PRINT "YOU'RE VERY HUNGRY": GO SUB 4990: RETURN
4700 RESTORE 9200: LET PK=INT (RND*5): FOR K=O TO PK: READ M$: NEXT K: RESTORE 9205: LET PK=INT (RND*5): FOR K=O TO PK: READ U$: NEXT K: RESTORE 9210: LET PK=INT (RND*6): FOR K=O TO PK: READ E$: NEXT K: LET BS=INT (RND*90)+11: RETURN
4701 RESTORE VAL "9215": LET PK=INT (RND*7): FOR K=O TO PK: READ F$: NEXT K: RETURN
4710 LET J=O: LET JI=O: LET IJ=O: IF I(INT PI)=U AND I(5)>=U THEN LET J=INT (RND*20)+U: GO TO VAL "4712"
4711 GO TO VAL "4714"
4712 IF J>I(5) THEN LET J=I(5)
4713 LET I(5)=I(5)-J
4714 IF I(4)=U AND I(6)>=U THEN LET JI=INT (RND*20)+U: GO TO VAL "4716"
4715 GO TO VAL "4718"
4716 IF JI>I(6) THEN LET JI=I(6)
4717 LET I(6)=I(6)-JI
4718 IF I(7)=U AND I(8)>=U THEN LET IJ=INT (RND*20)+U: GO TO VAL "4720"
4719 GO TO VAL "4722"
4720 IF IJ>I(8) THEN LET IJ=I(8)
4721 LET I(8)=I(8)-IJ
4722 LET BU=IJ+JI+J: PRINT : PRINT "YOU USED ";BU;" BULLETS": GO SUB VAL "4960": RETURN
4730 LET GS=O: IF I(3)=U THEN LET GS=GS+(INT (I(5)/20)*2)
4732 IF I(4)=U THEN LET GS=GS+(INT (I(6)/30)*5)
4734 IF I(7)=U THEN LET GS=GS+(INT (I(8)/30)*8)
4736 IF I(9)=U THEN LET GS=GS+R
4738 PRINT : PRINT "YOU HAVE ";CS;" STRENGTH": PRINT "HOW MUCH WILL YOU USE ?": GO SUB VAL "4960": INPUT "ENTER AMOUNT "; LINE E$: LET E$=E$+" ": IF CODE E$(U)>47 AND CODE E$(U)<58 THEN GO TO VAL "4740"
4739 GO TO VAL "4738"
4740 LET K=VAL E$: IF K>CS THEN PRINT : PRINT "YOU DON'T HAVE THAT MUCH": GO TO VAL "4738"
4742 IF K<10 THEN LET GS=O
4744 LET CS=CS-K: LET K=K+GS: IF K>=BS*1.5 THEN PRINT : PRINT "YOU ANNIHILATED THAT ONE!": LET SC=SC+BS: GO SUB VAL "4710": GO SUB VAL "4990": RETURN
4746 IF K<BS THEN GO TO VAL "4750"
4748 IF RND*9>PI THEN PRINT : PRINT "YOU MADE A MESS OF HIM!": LET SC=SC+BS: GO SUB VAL "4710": GO SUB VAL "4990": RETURN
4750 IF FO>O THEN PRINT : PRINT "YOU GOT HAMMERED THAT TIME!": GO TO VAL "4760"
4752 PRINT : PRINT "NOW THE ";F$;" IS ANNOYED": LET FO=PI: GO SUB VAL "4710": GO SUB VAL "4990": GO TO VAL "4123"
4760 IF F$="BUFFALO" OR F$="RATTLE SNAKE" OR F$="SCORPION" OR F$="VULTURE" OR F$="LONGHORN" OR F$="GRIZZLY BEAR" OR F$="MOUNTAIN LION" THEN GO TO VAL "4790"
4761 LET CU=O: FOR T=U TO 16: LET CU=CU+I(T): NEXT T: IF CU<=O AND MU<=4 THEN GO TO VAL "4770"
4762 IF MU>=4 AND RND*5>4 THEN PRINT : PRINT "THE ";F$;" TAKES $";INT (MU/2): LET MU=INT (MU/2): GO SUB VAL "4960": RETURN
4764 IF CU<=O THEN GO TO VAL "4762"
4765 LET CU=INT (RND*16)+U: IF I(CU)<=O THEN GO TO VAL "4765"
4767 LET I(CU)=O: PRINT : PRINT "THE ";F$;" TAKES YOUR": PRINT K$(CU): GO SUB VAL "4960": RETURN
4770 PRINT : PRINT "THE ";F$;" LEAVES": GO SUB VAL "4960": RETURN
4780 LET SC=SC-10: LET CS=CS-10: GO SUB VAL "4990": IF I(U)>=U AND RND*8>5 THEN PRINT : PRINT "O.K YOU MADE IT": RETURN
4781 PRINT : PRINT "UNFORTUNATELY HE'S A QUICK": PRINT M$;",";U$;" ";F$: GO TO VAL "4123"
4790 IF I(10)>O THEN LET I(10)=O: PRINT : PRINT "THE ";F$;"TAKES ": PRINT "YOUR FOOD": GO SUB VAL "4960": RETURN
4791 IF I(11)>O THEN LET I(11)=O: PRINT "THE ";F$;" TAKES": PRINT "YOUR HORSES FOOD": GO SUB VAL "4960": RETURN
4792 IF I(12)>O AND DE=U THEN LET I(12)=O: PRINT : PRINT "THE ";F$;" TAKES": PRINT "YOUR WATER": GO SUB VAL "4960": RETURN
4793 GO SUB VAL "4990": PRINT : PRINT "THE ";F$;" ATTACKS AGAIN": GO TO VAL "4123"
4795 IF TS=PI THEN GO TO VAL "4805"
4796 LET BB=INT (RND*50)+U: LET BF=O: FOR T=16 TO U STEP -U: LET BF=I(T)*K(T)
4797 IF T=5 OR T=6 OR T=8 THEN LET BF=BF/50
4798 IF BF>=BB THEN LET BF=T: GO TO VAL "4805"
4799 LET BF=T
4800 NEXT T
4805 IF MU<=O THEN PRINT : PRINT "YOU HAVE NO MONEY": LET TS=PI: RETURN
4808 PRINT : PRINT "YOU HAVE $";MU: PRINT "HOW MUCH DO YOU OFFER?": BEEP .5,20: INPUT "ENTER AMOUNT "; LINE E$: LET E$=E$+" ": IF CODE E$(U)>47 AND CODE E$(U)<57 THEN GO TO VAL "4810"
4809 GO TO VAL "4808"
4810 LET YB=VAL E$: IF YB>MU THEN GO TO VAL "4808"
4812 IF F$="BUFFALO" OR F$="RATTLE SNAKE" OR F$="SCORPION" OR F$="VULTURE" OR F$="LONGHORN" OR F$="GRIZZLY BEAR" OR F$="MOUNTAIN LION" THEN PRINT : PRINT "WHAT IS A ";F$;" GOING": PRINT "TO DO WITH $";YB;" ?": LET TS=PI: RETURN
4815 IF YB>=BB THEN PRINT : PRINT "THE ";F$;" ACCEPTS": LET MU=MU-YB: LET TS=0: RETURN
4820 IF I(BF)*K(BF)>=BB THEN PRINT : PRINT "THE ";F$;" IS DISGUSTED": PRINT "HE TAKES YOUR ";K$(BF): LET I(BF)=0: LET TS=O: LET BF=O: RETURN
4825 PRINT : PRINT "THE ";F$;" ATTACKS YOU": LET TS=PI: RETURN
4845 LET DI=O: IF I(12)<U THEN LET CS=CS-30: PRINT : PRINT "YOU ARE VERY THIRSTY": RETURN
4846 LET I(12)=I(12)-U: LET CS=CS+10: RETURN
4850 IF I(U)=U AND I(12)<1 THEN PRINT : PRINT "YOUR HORSE NEEDS WATER": LET HS=HS-2: RETURN
4851 LET I(12)=I(12)-U: LET CS=CS+10: RETURN
4855 IF I(U)=O THEN RETURN
4856 IF I(11)<=O AND DE=U THEN PRINT : PRINT "HORSES DON'T EAT SAND": LET HS=HS-U
4857 IF I(11)<=O AND MT=U THEN PRINT : PRINT "HORSES DON'T EAT ROCKS": LET HS=HS-U
4858 IF I(11)>O THEN LET I(11)=I(11)-U
4859 GO SUB VAL "4975": RETURN
4860 LET MI=O: IF I(13)<U THEN LET CS=CS-10
4861 IF I(15)<U THEN LET CS=CS-15
4862 PRINT : PRINT "YOU ARE VERY COLD": RETURN
4870 GO SUB VAL "4960": IF INT (RND*18)+U>8 THEN LET GN=INT (RND*100)+U: PRINT : PRINT "YOU FIND A GOLD NUGGET WORTH $";GN: LET MU=MU+GN: RETURN
4871 LET GN=INT (RND*7)+10: LET I(GN)=I(GN)+U: PRINT : PRINT "YOU FIND ";K$(GN): RETURN
4950 PRINT : PRINT "WILL YOU RUN,FIGHT OR BRIBE ?": BEEP .5,20: INPUT "ENTER R,F OR B "; LINE H$: IF H$="R" OR H$="F" OR H$="B" THEN RETURN
4955 GO TO VAL "4950"
4960 BEEP .2,20: BEEP .2,10: BEEP .2,15: RETURN
4970 IF HL=U THEN LET KK=KK-U: RETURN
4971 PRINT : PRINT "YOUR HORSE GOES LAME": LET HS=HS-U: LET HL=U: PRINT "THIS ADDS 2 DAYS TO YOUR JOURNEY": LET N=N-R
4975 IF I(U)=O THEN RETURN
4976 IF HS<=U THEN LET I(U)=O: PRINT : PRINT "YOUR HORSE IS DEAD": GO SUB VAL "9226": RETURN
4990 IF CS<=O THEN PRINT : PRINT "YOU'RE DEAD.....": LET M$="YOU RAN OUT OF STRENGTH!": GO TO VAL "5270"
4991 RETURN
5002 BORDER U: CLS : PRINT AT 9,U;"YOU BOTH WALK INTO THE STREET ",,," FOR A FIGHT TO THE DEATH."
5003 RESTORE VAL "9080": FOR N=U TO 10: READ K: READ G: BEEP K/3,G: NEXT N
5004 LET SF=O: PAPER O: BORDER INT PI: CLS
5006 IF I(INT PI)+I(4)<=O THEN LET M$="YOU DIDN'T HAVE A GUN!": GO TO VAL "5012"
5007 IF I(5)+I(6)<=O THEN LET M$="YOU DIDN'T HAVE ANY BULLETS!": GO TO VAL "5012"
5008 IF I(INT PI)>O AND I(5)<=O AND I(6)>=O OR I(4)>O AND I(5)>O AND I(6)<=O THEN LET M$="YOUR BULLETS DIDN'T FIT YOUR GUN": GO TO VAL "5012"
5010 LET Y=O: LET M$="YOU WERE NOT FAST ENOUGH!": GO TO VAL "5018"
5012 LET Y=U
5019 POKE 23606,247: POKE 23607,242: PRINT " !""#$ %",," &'()* +";TAB 25;",-. /0123 4";TAB 25;"567 89:;<= >";TAB 25;"?@A BCDEF G";TAB 0;"HIJKL MN",,"OP QRSTU VW";TAB 21;"XYZ\] ↑_£abcdefghijklm";TAB 20;"no pqrst uvwxyz {|}~©"
5030 POKE 23607,245: PRINT AT 8,13;"! ""# $%&'()* +,-./0123456789 :;< = >?@AB C DEFGHIJKLMNO PQR STUVWXYZ[\]↑_£abcdefghij klmno pqrstuv wxyz{|}~ ©"
5050 POKE 23607,248: PRINT AT 12,11;"!""#$ %&'()* +,-./012345 6789: ;<=>?@ABC D EFGHIJKLMNOP";TAB 21;"QRSTUVW X YZ[\]↑_";TAB 24;"£abcdefghi";TAB 25;"jklmnop";TAB 26;"qrstuvwxy";TAB 28;"z {|}~©";TAB 32
5070 POKE VAL "23606",VAL "254": POKE VAL "23607",VAL "251": PRINT "£[]{";TAB 0;"}";TAB 32
5120 PRINT PAPER 5;AT 10,15;"abc";AT 11,15; PAPER 6;"def";AT 12,15;"ghi";AT 13,15;"jkl";AT 14,15;"m n"
5125 LET K=INT (RND*4)+2: FOR D=U TO K: RESTORE VAL "9035": FOR N=U TO 20: READ H: READ F: BEEP H/3,F
5130 IF INKEY$<>"" AND Y=0 THEN LET SF=1: GO TO VAL "5300"
5135 NEXT N: NEXT D
5200 PRINT PAPER 6;AT 11,15;"oep";AT 12,15;"qhr"
5210 LET M=INT (RND*5)+5: FOR N=1 TO M
5215 IF INKEY$<>"" AND Y=0 THEN GO TO VAL "5300"
5220 NEXT N
5250 PRINT PAPER 6;AT 11,15;"set";AT 12,15;"uhv"
5255 FOR N=-20 TO 20: BEEP .05,N: BEEP .1,N*-1.5: NEXT N
5260 PAPER O: INK VAL "9": BORDER O: CLS
5265 PRINT AT 10,10;"HE SHOT YOU!"
5270 RESTORE VAL "9100": FOR N=U TO 11: READ M: READ W: BEEP M/3,W: NEXT N
5280 GO TO VAL "8500"
5300 PRINT PAPER 6;AT 11,15;"wex";AT 12,15;"yz\"
5305 PLOT 128,100: DRAW -9,18: PRINT PAPER VAL "5";AT 6,12;"AAAGGH!"
5310 FOR N=O TO 40: BEEP .002,N: NEXT N
5315 RESTORE VAL "9080": FOR N=U TO 10: READ M: READ W: BEEP M/3,W: NEXT N
5320 IF SF=U THEN GO TO VAL "5405"
5325 PAPER 4: INK 9: BORDER U: CLS : PRINT AT 6,2;"YOU CARRY THE BODY TO THE": PRINT : PRINT " SHERIFFS OFFICE.....": GO SUB VAL "2455": GO TO VAL "2460"
5405 PAPER O: INK VAL "9": BORDER O: CLS
5410 PRINT AT 7,9;"YOU DREW FIRST!": PRINT : PRINT TAB 9;"THAT'S MURDER.": PRINT : PRINT : PRINT TAB 5;"THE SHERIFF ARRESTS YOU": PRINT : PRINT TAB 8;"YOU'LL BE IN JAIL": PRINT : PRINT TAB 8;"FOR QUITE A WHILE": GO TO 2725
6000 GO SUB VAL "300": PRINT AT 17,1;"YOU ARE IN (";TN;")";T$(TN): PRINT : PRINT TAB 4;"WHERE DO YOU WANT TO GO?"
6005 INPUT "ENTER NUMBER OF DESTINATION "; LINE E$: LET E$=E$+" ": IF CODE E$(U)<49 OR CODE E$(U)>53 THEN GO TO VAL "6005"
6025 LET FL=VAL E$: IF FL<U OR FL>5 OR FL=TN THEN GO TO VAL "6005"
6028 LET G=T(TN,FL)
6030 IF G<-10 THEN LET DE=O: LET MT=U: LET G=G/-3: LET P$="MOUNTAINS": GO TO VAL "6045"
6035 IF G<O THEN LET DE=U: LET MT=O: LET G=G*-U: LET P$="DESERT": GO TO VAL "6045"
6040 LET P$="OPEN RANGE": LET MT=O: LET DE=O
6045 PRINT AT 19,U;T$(FL);" IS ";G;" DAYS RIDE"," ACROSS THE ";P$: BEEP .3,7: BEEP .2,14: BEEP .3,-7
6050 INPUT " PRESS ENTER TO CONTINUE"; LINE H$
6060 PAPER 4: BORDER U: CLS : PRINT AT 4,4;"DO YOU WANT TO:": PRINT : PRINT TAB 5;"A) START YOUR JOURNEY": PRINT : PRINT TAB 5;"B) BUY PROVISIONS": PRINT : PRINT TAB 5;"C) LOOK AT MAP AGAIN";AT 14,3;"PRESS LETTER OF YOUR CHOICE"
6065 BEEP .01,5: IF INKEY$="A" THEN GO TO VAL "4000"
6070 IF INKEY$="B" THEN GO TO VAL "7660"
6075 IF INKEY$="C" THEN GO TO VAL "6000"
6080 BEEP .02,29: GO TO VAL "6065"
7000 PAPER VAL "7": INK VAL "9": CLS
7001 PRINT " ": PRINT " ": PRINT " ": PRINT " "
7005 PRINT AT 7,4;"DEAD";AT 7,23;"DEAD";AT 9,5;"OR";AT 9,24;"OR";AT 11,4;"ALIVE";AT 11,23;"ALIVE";AT 13,4;"$";R(L);AT 13,23;"$";R(L)
7010 PLOT 117,135: DRAW -7,-17: DRAW 18,-10: DRAW O,15: DRAW 10,12: DRAW 8,-17: DRAW -18,-10: PLOT 127,123: DRAW -10,12: DRAW 10,-9: DRAW 11,9: PLOT 145,120: DRAW 15,-R: DRAW -32,-12: PLOT 127,106: DRAW -32,12: DRAW 15,R
7015 PLOT VAL "111",VAL "112": DRAW VAL "6",VAL "-30": PLOT VAL "145",VAL "112": DRAW VAL "-6",VAL "-30": DRAW VAL "-22",O,-PI
7020 IF D$(L)<>"NO RIGHT EAR......." THEN PLOT VAL "112",VAL "108": DRAW VAL "-4",O,PI: DRAW VAL "6",VAL "-13"
7025 IF D$(L)<>"NO LEFT EAR........" THEN PLOT VAL "144",VAL "108": DRAW VAL "4",O,-PI: DRAW VAL "-6",VAL "-13"
7030 PLOT VAL "132",VAL "82": PLOT VAL "131",VAL "83": DRAW VAL "-7",O: PLOT VAL "123",VAL "82"
7035 PLOT VAL "126",VAL "90": PLOT VAL "128",VAL "90": PLOT VAL "127",VAL "92": PLOT VAL "127",VAL "95": PLOT VAL "127",VAL "97": PLOT VAL "127",VAL "98": PLOT VAL "127",VAL "101"
7040 PLOT VAL "116",VAL "104": PLOT VAL "116",VAL "105": DRAW VAL "3",O: PLOT VAL "119",VAL "104": PLOT VAL "120",VAL "104": PLOT VAL "119",VAL "105"
7045 PLOT VAL "138",VAL "105": DRAW VAL "-3",O: PLOT VAL "136",VAL "104": DRAW VAL "-3",0: PLOT VAL "135",VAL "106": PLOT VAL "139",VAL "104"
7050 PLOT VAL "134",VAL "101": DRAW VAL "3",O: PLOT VAL "133",VAL "102": PLOT VAL "123",VAL "102": PLOT VAL "119",VAL "101": DRAW VAL "3",O
7055 IF D$(L)<>"NO EYEBROWS........" THEN PLOT VAL "132",VAL "105": PLOT VAL "131",VAL "105": PLOT VAL "131",VAL "104": PLOT VAL "135",VAL "107": DRAW VAL "4",O: PLOT VAL "132",VAL "106": DRAW VAL "4",O: PLOT VAL "123",VAL "104": PLOT VAL "123",VAL "105": PLOT VAL "122",VAL "105": PLOT VAL "119",VAL "106": DRAW VAL "4",O: PLOT VAL "116",VAL "107": DRAW VAL "5",O
7060 PLOT VAL "114",VAL "95": DRAW O,VAL "16": PLOT VAL "113",VAL "98": DRAW O,VAL "13": PLOT VAL "112",VAL "105": DRAW O,VAL "7": PLOT VAL "142",VAL "96": DRAW O,VAL "15": PLOT VAL "143",VAL "98": DRAW O,VAL "13": PLOT VAL "144",VAL "105": DRAW O,VAL "7"
7065 PLOT 138,70: DRAW O,10: PLOT 117,70: DRAW O,11: PLOT 100,64: DRAW 14,O: DRAW O,6: PLOT 116,71: PLOT 115,71: DRAW 8,-4: DRAW O,-9: PLOT 121,66: PLOT 120,65: DRAW O,-3: PLOT 119,61: PLOT 118,61: DRAW -3,3: PLOT 132,58: DRAW O,9: DRAW 7,3: PLOT 133,67: DRAW 3,-6: DRAW 4,3: DRAW O,5: PLOT 140,64: DRAW 12,O
7070 IF D$(L)="SCAR ON RIGHT CHEEK" THEN PLOT 119,89: DRAW 3,7
7075 IF D$(L)="SCAR ON LEFT CHEEK." THEN PLOT 136,89: DRAW -3,7
7080 IF D$(L)="A LEFT EARING......" THEN PLOT 147,104: PLOT 148,103: PLOT 148,102: PLOT 147,101
7085 IF D$(L)="A RIGHT EARING....." THEN PLOT 109,103: PLOT 109,101: PLOT 108,102: PLOT 108,103
7090 IF D$(L)="A MOUSTACHE........" THEN PLOT 128,87: DRAW 4,O: PLOT 128,86: DRAW 4,O: PLOT 128,85: DRAW 5,O: PLOT 134,84: PLOT 133,84: PLOT 126,87: DRAW -3,O: PLOT 126,86: DRAW -4,O: PLOT 126,85: DRAW -4,O: PLOT 121,84: PLOT 122,84
7095 IF D$(L)="PATCH ON LEFT EYE.." THEN PLOT 132,101: DRAW 5,O: PLOT 132,102: DRAW 6,O: PLOT 132,103: DRAW 7,O: PLOT 132,104: DRAW 7,O: PLOT 129,105: DRAW 10,O: PLOT 133,106: DRAW 6,O: PLOT 135,107: DRAW 4,O: PLOT 140,108: PLOT 141,108
7100 IF D$(L)="PATCH ON RIGHT EYE." THEN PLOT 115,107: DRAW 6,O: PLOT 116,106: DRAW 10,O: PLOT 116,105: DRAW 7,O: PLOT 116,104: DRAW 7,O: PLOT 116,103: DRAW 7,O: PLOT 116,102: DRAW 7,O: PLOT 117,101: DRAW 5,O
7105 LET L$="SEE PICTURE": IF D$(L)="A LIMP IN LEFT LEG." THEN LET L$="LIMPS WITH LEFT LEG"
7107 IF D$(L)="A LIMP IN RIGHT LEG" THEN LET L$="LIMPS WITH RIGHT LEG"
7110 IF L=R THEN PRINT AT 15,9;B$(L);TAB 6;"ALIAS-THE SUNDANCE KID"," FOR-MURDER:HORSE AND CATTLE RUSTLING:BANK AND TRAIN ROBBERY",,,"DESCRIPTION-";L$
7115 IF L=3 THEN PRINT AT 15,10;B$(L);TAB 2;"ALIAS-KID CURRY:TOM CAPEHART: BOB NEVILLES";TAB 3;"FOR-MURDER:TRAIN ROBBERY",,,"DESCRIPTION-";L$
7120 IF L=5 THEN PRINT AT 15,9;B$(L): PRINT " ALIAS-THE TALL TEXAN:J.D.ROSE:","FOR:CATTLE RUSTLING:MURDER:FRAUDBANK AND TRAIN ROBBERY",,,"DESCRIPTION-";L$
7125 IF L=U THEN PRINT AT 15,10;B$(L)," ALIAS-BUTCH CASSIDY:JIM LOWE"," FOR-HORSE AND CATTLE RUSTLING"," TRAIN,BANK AND PAYROLL ROBBERY",,,"DESCRIPTION-";L$
7130 IF L=4 THEN PRINT AT 15,12;B$(L)," ALIAS-WILLIAM MCGUINNNESS"," FOR-MURDER:PAYROLL ROBBERY"," HORSE AND CATTLE RUSTLING",,,"DESCRIPTION-";L$
7140 INPUT " PRESS ENTER TO CONTINUE"; LINE H$
7145 GO TO 501
7500 LET CS=CS+VAL "50": LET TP=O: LET GF=O: LET L1=L
7510 LET L=INT (RND*5)+U: IF L=L1 THEN GO TO 7510
7515 IF V(L)<R THEN GO TO 7510
7520 IF L=MB AND V(U)+V(R)+V(INT PI)+V(4)+V(5)>6 THEN GO TO 7510
7525 LET TN=FL
7530 IF JB=O AND RND*5>4 THEN GO TO 7540
7532 LET IS=0: LET LM=LM+INT (RND*2)+U
7535 RETURN
7540 FOR N=U TO 5: IF V(N)=U THEN LET JB=N: LET R(N)=R(N)+50: LET V(N)=R: GO TO 7650
7545 NEXT N
7650 RETURN
7666 LET Z=3: BORDER U: PAPER U: CLS : PRINT TAB 6;"YOU ARE IN THE STORE": PRINT : FOR N=U TO 16: IF N>9 THEN LET Z=R
7667 BEEP .1,N: PRINT TAB Z;N;") ";K$(N);"$";K(N): NEXT N
7668 PRINT AT 19,9;"YOU HAVE $";MU;" ": PRINT
7669 PRINT PAPER 2;" WHICH ITEMS DO YOU REQUIRE? "
7670 INPUT " ENTER NUMBER (0 TO LEAVE) "; LINE E$: LET E$=E$+" ": IF CODE E$(U)>57 OR CODE E$(U)<48 THEN GO TO VAL "7670"
7672 LET Z=VAL E$: IF Z=O THEN GO TO VAL "500"
7675 IF Z>16 THEN GO TO VAL "7670"
7680 BEEP .2,Z: BEEP .1,Z*-U: PRINT PAPER 1;AT 21,U;S$
7681 IF Z<5 AND I(Z)=U THEN GO TO VAL "7685"
7682 IF Z=7 AND I(Z)=U THEN GO TO VAL "7685"
7683 IF Z=9 AND I(Z)=U THEN GO TO VAL "7685"
7684 GO TO VAL "7686"
7685 PRINT AT 21,O;" YOU ALREADY HAVE ONE ": FOR N=-10 TO 30: BEEP .05,N: BEEP .05,N+R: NEXT N: PRINT AT 21,U;S$: GO TO 7668
7686 PRINT PAPER 5;AT 21,O;" HOW MANY WOULD YOU LIKE? "
7687 INPUT " ENTER QUANTITY REQUIRED "; LINE E$: LET E$=E$+" ": IF CODE E$(U)<47 OR CODE E$(U)>57 THEN GO TO VAL "7687"
7690 LET Q=VAL E$: IF Q<=O THEN GO TO VAL "7668"
7691 IF Z<5 AND Q>U THEN GO TO VAL "7695"
7692 IF Z=7 AND Q>U THEN GO TO VAL "7695"
7693 IF Z=9 AND Q>U THEN GO TO VAL "7695"
7694 GO TO VAL "7696"
7695 PRINT AT 21,O;" YOU CAN ONLY HAVE ONE ": FOR N=-10 TO 30: BEEP .05,N: BEEP .05,N+R: NEXT N: PRINT AT 21,U;S$: GO TO 7668
7696 IF MU<Q*K(Z) THEN PRINT FLASH U;AT 21,U;" YOU CAN'T AFFORD IT! ": GO SUB 9231: GO TO 7668
7700 IF Z=8 OR Z=6 OR Z=5 THEN LET I(Z)=I(Z)+Q*50: LET MU=MU-Q*K(Z): GO TO VAL "7710"
7705 LET MU=MU-Q*K(Z): LET I(Z)=I(Z)+Q
7710 BEEP .3,20: BEEP .3,30: GO TO VAL "7668"
7810 PAPER O: BORDER O: CLS : PRINT PAPER 2;"STATUS OF ";N$: PRINT : PRINT "YOU HAVE $";MU: PRINT "YOUR COMBAT STRENGTH IS ";CS: PRINT : PRINT "YOU HAVE THE FOLLOWING:": FOR N=U TO 16: IF I(N)>O THEN PRINT K$(N);I(N)
7820 NEXT N: BEEP .5,6: BEEP .4,-6: INPUT "PRESS ENTER TO CONTINUE "; LINE H$: GO TO VAL "500"
8500 CLS : PRINT AT 6,O;"YOU WENT TO THE GREAT RANCH IN": PRINT : PRINT "THE SKY BECAUSE :": PRINT : PRINT M$: FOR N=O TO -30 STEP -U: BEEP .2,N: NEXT N: GO SUB 9500: GO TO 9850
8900 BORDER O: PAPER O: CLS
8905 PRINT AT 1,6;"THE STORY SO FAR....",,," YOU ARE WALKING HOME ONE NIGHT WHEN YOU HEAR A GUNSHOT."," YOU FIND A DYING MAN LYING IN"," THE ROAD.HE MUTTERS THE WORDS; ""THE WILD BUNCH...THE MAN WITH"
8910 PRINT " ";D$(MB);""""
8915 PRINT AT 10,R;"THE MAN COUGHS AND DIES."," YOU PICK UP A COLT 45 THAT MUST BELONG TO THE MURDERER."," AT THAT MOMENT THE SHERIFF"," RIDES UP.HE SEES YOU WITH THE BODY AND THE GUN IN YOUR HAND. HE SHOUTS;""DON'T MOVE OR I'LL FILL YOU FULL OF LEAD!"""," YOU RUN OFF INTO THE NIGHT WITH BULLETS FLYING PAST YOUR HEAD."
8920 PRINT AT 21,12; PAPER 6;"ANY KEY": GO SUB 8925: GO TO VAL "8950"
8925 LET Y=U
8928 FOR L=U TO R: RESTORE VAL "9020"
8930 FOR N=Y TO 26: IF L=R AND N=24 THEN RESTORE 9025
8932 READ z: READ x: BEEP z/2.5,x: IF INKEY$<>"" THEN RETURN
8935 NEXT N: NEXT L
8940 PAUSE 30: GO TO VAL "8925"
8950 CLS : PRINT AT 7,6;"YOU ARE A WANTED MAN",,," YOUR ONLY CHANCE TO PROVE YOUR INNOCENCE IS TO FIND THE REAL KILLER A MEMBER OF THE DREADED": PRINT : PRINT TAB 10;"""WILD BUNCH!""": PRINT : PRINT : PRINT TAB 12; PAPER 6;"ANY KEY"
8960 LET Y=N+U: GO SUB VAL "8930"
8965 GO SUB VAL "300"
8970 PRINT AT 18,U;"YOU HAVE $50.YOU MAY CATCH THE STAGE TO ANY OF THE ABOVE TOWNS TO START YOUR SEARCH."
8975 INPUT " ENTER TOWN NUMBER "; LINE E$: LET E$=E$+" ": IF CODE E$(1)>53 OR CODE E$(1)<49 THEN GO TO 8975
8976 LET TN=VAL E$: IF TN>5 THEN GO TO VAL "8975"
8977 LET UM=INT (RND*5)+U: IF UM=TN THEN GO TO VAL "8977"
8980 LET FL=TN: LET MU=50: GO TO VAL "480"
9001 DATA "PATCH ON RIGHT EYE."
9002 DATA "SCAR ON LEFT CHEEK."
9003 DATA "NO LEFT EAR........"
9004 DATA "PATCH ON LEFT EYE.."
9005 DATA "SCAR ON RIGHT CHEEK"
9006 DATA "A LEFT EARING......"
9007 DATA "A LIMP IN LEFT LEG."
9008 DATA "NO EYEBROWS........"
9009 DATA "NO RIGHT EAR......."
9010 DATA "A LIMP IN RIGHT LEG"
9011 DATA "A MOUSTACHE........"
9012 DATA "A RIGHT EARING....."
9015 DATA "GEORGE PARKER","HARRY LONGBOUGH","HARVEY LOGAN","ELZA LAY","BEN KILPATRICK"
9020 DATA U,15,1.5,15,.5,13,.75,12,U,13,U,15,U,13,U,12,.5,10,U,8,U,7,1.5,3,.1,-60,.1,-60,.1,-60,.5,3,U,8,.5,8,U,8,U,10,U,12,U,13,U,12,U,10,U,8,R,10
9025 DATA U,8,U,10,R,8
9035 DATA 1.5,7,.75,14,U,10,1.5,12,U,10,U,12,1.5,14,1.5,19,1.5,17,U,19,.1,-60,.1,-60,.1,-60,1.25,7,.75,14,U,10,1.5,12,U,9,U,5,R,7
9045 DATA "DRY GULCH","DODGE CITY","NUGGET CITY","BULLETVILLE","DEADMANS CREEK"
9050 DATA 3,12,1,10,1,9,1,7,2,9
9060 DATA "8%"
9061 DATA "9&"
9062 DATA "K&"
9063 DATA "7@ 7&"
9064 DATA "8& 8@"
9065 DATA "A@ A&"
9066 DATA "K# K@ 9@ 9%"
9067 DATA "10# 10@ 10&"
9068 DATA "Q@ Q& Q#"
9069 DATA "4@ 5@ 6& 7% 8#"
9070 DATA "5# 6# 7# 9# A#"
9071 DATA "4% 4# 4& 5& 5%"
9072 DATA "J# J& J@ 6@ 6#"
9073 DATA "2# 2% 2& 2@"
9074 DATA "3% 3& 3@ 3#"
9075 DATA "10% J% Q% K% A%"
9080 DATA U,9,U,7,R,9,R,R,U,4,U,5,U,9,U,9,U,7,R,4
9085 DATA U,11,U,11,U,9,U,8,U,8,U,7,U,8,R,8
9090 DATA U,7,U,8,U,8,U,7,U,8,U,11,U,8,U,11,R,9,R,6
9095 DATA 200,100,100,250,125
9100 DATA R,R,R,R,U,R,R,R,R,5,U,4,R,4,U,R,R,R,U,U,R,R
9110 DATA O,5,3,-21,-10,5,O,2,5,-6,3,R,O,-15,-7,-21,5,-15,O,R,-10,-6,-7,R,O
9120 DATA R,3,U,4,3,R,U,R,3,R,5,4,R,4,5
9140 DATA "HORSE---------------","SADDLE--------------",".44 COLT------------",".45 COLT------------","COLT .44 BULLETS----","COLT .45 BULLETS----","WINCHESTER RIFLE----","WINCHESTER BULLETS--","KNIFE---------------","FOOD FOR 1 DAY------","HORSE FOOD FOR 1 DAY","CANTEEN OF WATER----","GREAT COAT----------","WHISKEY-------------","BLANKET-------------","SNAKEBITE MEDICINE--"
9145 DATA 55,28,35,35,5,10,40,15,10,R,3,3,15,R,8,4
9151 DATA "THE BLACKSMITH"
9152 DATA "THE TOWN MAYOR"
9153 DATA "THE DOCTOR"
9154 DATA "MY DEPUTY"
9200 DATA "MEAN","TOUGH","BIG","CRUEL","MAD"
9205 DATA "NASTY","UGLY","VICIOUS","ANGRY","DESPERATE"
9210 DATA "JUMPS OUT ON YOU","SPRINGS OUT","WANDERS UP TO YOU","ATTACKS YOU","CHARGES TOWARD YOU","SNEAKS UP TO YOU"
9215 DATA "RED INDIAN","BANDIT","GUNSLINGER","BOUNTY HUNTER","TRAPPER","DESPERADO","VULTURE"
9225 DATA R,5,R,10,U,10,R,10,R,14,R,12,U,10,R,12,U,14,U,12,R,10,U,10,R,14,R,17,3,19
9226 RESTORE VAL "9225": FOR W=U TO 15: READ X: READ E: BEEP X/5,E: NEXT W: PAUSE 100: RETURN
9230 DATA U,13,1.25,20,.75,18,R,20,U,18,.5,13,U,16,.5,13,U,16,R,15
9231 RESTORE VAL "9230": FOR W=U TO 10: READ X: READ E: BEEP X/3,E: NEXT W: RETURN
9505 BEEP .5,PI: INPUT "PRESS ENTER FOR SCORE "; LINE H$: IF MU>50 THEN LET SC=SC+MU-50
9520 IF SC>HC THEN LET HC=SC: LET Q$=N$
9521 RETURN
9525 INK 9: PRINT AT 17,5;"YOU HAVE SCORED ";SC: PRINT : PRINT TAB 4;"BEST SCORE SO FAR IS ";HC: PRINT : PRINT TAB 4;"BY ";Q$: INPUT "PRESS ENTER FOR ANOTHER GAME"; LINE H$: GO TO 15
9600 FOR N=U TO 6: FOR X=O TO 7: BORDER X: PAPER N: CLS : BEEP .01,N*X+10: NEXT X: NEXT N
9605 PRINT FLASH U;AT 4,4;"****CONGRATULATIONS****": PRINT : PRINT : PRINT " THE KILLER WAS ";B$(A): PRINT : PRINT " HE CONFESSED,WHEN THE SHERIFF": PRINT : PRINT " LOCKED HIM UP...": PRINT : PRINT " YOU'RE A HERO,YOU HAVE SAVED": PRINT : PRINT " THE WEST FROM THE WILD BUNCH!": LET SC=SC+5000: LET F$="HERO!": GO TO 9720
9700 FOR N=U TO 6: FOR X=7 TO 0 STEP -U: BORDER N: PAPER X: CLS : BEEP .01,N*-U: NEXT X: NEXT N
9710 PRINT AT 5,U;"UNFORTUNATELY YOU HAVE JUST": PRINT : PRINT " KILLED THE ONLY MAN WHO COULD": PRINT : PRINT " PROVE YOUR INNOCENCE. DEAD MEN": PRINT : PRINT " DON'T CONFESS....": LET F$="IDIOT"
9720 GO SUB VAL "9500": GO TO VAL "9800"
9800 PAPER R: BORDER R: CLS : LET X=62298: LET T=8: GO SUB 9900: DRAW -17,29: PLOT 139,137: DRAW -16,28: PLOT 73,137: DRAW 17,-30: PLOT 107,78: DRAW 16,-30: PRINT AT 6,14;"TOP";AT 8,13;"GRADE";AT 10,13;F$: GO TO 9525
9850 BORDER R: PAPER R: INK O: CLS : LET S$="": FOR N=U TO 13: PRINT AT N,13;S$: NEXT N: FOR N=4 TO 6: PRINT AT N,10;S$;S$;S$: NEXT N: INK 9: PRINT PAPER O;AT 5,12;"R.I.P": GO TO 9525
9870 PAPER R: BORDER R: INK 0: CLS : LET X=62331: LET T=29: PRINT AT R,9;"";AT 14,9;"": FOR N=INT PI TO 13: PRINT PAPER 5;AT N,9;" ": NEXT N: GO SUB 9900: LET X=62240: FOR N=1 TO 28: PLOT PEEK X,PEEK (X+1): LET X=X+2: NEXT N
9871 PLOT 108,95: DRAW 28,O,PI: PLOT 126,73: DRAW -3,R: PLOT 116,86: DRAW 12,O,-PI: PLOT 127,110: DRAW 5,3,-PI/R: PLOT 117,110: DRAW -5,3,PI/R: PLOT 147,72: DRAW 6,-8,-PI/R: PLOT 97,72: DRAW -6,-8,PI/R: GO TO 9525
9900 FOR N=U TO T: PLOT PEEK X,PEEK (X+U): LET X=X+R: DRAW PEEK X,PEEK (X+U): LET X=X+R: NEXT N: RETURN
9999 INK 9: BEEP .5,O: PAUSE O: GO TO VAL "15"