Booty: Routine at 57444

57444: Print Status Bar Icons

Used by the routines at InitialiseGame and PrintStatusBar.
PrintStatusBarIcons	57444	LD HL,61787	Write 61787 (Graphics_Spark) to *CHARS.
	57447	LD (23606),HL	Write 61787 (Graphics_Spark) to *CHARS.
Set up the screen buffer position.
	57450	LD C,33	Set up the screen buffer location 1/33 using CL_SET.
	57452	LD B,1
	57454	CALL 3545
Skip showing any lives if the player is using their last life.
	57457	LD A,(23537)	Jump to PrintKeyIcon if *PlayerLives is equal to 0.
	57460	CP 0
	57462	JR Z,PrintKeyIcon
Display a life icon for each life the player has.
	57464	LD B,A	B=PlayerLives (number of lives counter).
PrintLifeIcon_Loop	57465	LD A,33	A=Player life icon (33).
	57467	CALL PrintColourCharacter	Call PrintColourCharacter.
	57470	DJNZ PrintLifeIcon_Loop	Decrease lives counter by one and loop back to PrintLifeIcon_Loop until all lives have been printed.
Put a space between the lives and the key icon. Restore the default ZX Spectrum font.
PrintKeyIcon	57472	LD HL,15360	Write 15360 (CHARSET-256) to *CHARS.
	57475	LD (23606),HL	Write 15360 (CHARSET-256) to *CHARS.
	57478	LD A,32	A=ASCII "space" (32).
	57480	CALL PrintColourCharacter	Call PrintColourCharacter.
Set up the screen buffer position.
	57483	LD C,29	Set up the screen buffer location 1/29 using CL_SET.
	57485	LD B,1
	57487	CALL 3545
	57490	LD HL,61787	Write 61787 (Graphics_Spark) to *CHARS.
	57493	LD (23606),HL	Write 61787 (Graphics_Spark) to *CHARS.
Display the key icon.
	57496	LD A,34	A=Key icon left (34).
	57498	CALL PrintColourCharacter	Call PrintColourCharacter.
	57501	LD A,35	A=Key icon right (35).
	57503	CALL PrintColourCharacter	Call PrintColourCharacter.
Restore the default ZX Spectrum font.
	57506	LD HL,15360	Write 15360 (CHARSET-256) to *CHARS.
	57509	LD (23606),HL	Write 15360 (CHARSET-256) to *CHARS.
	57512	RET	Return.